Defining bindings for python(-ts)-mode fails mysteriously

Question

Setting up bindings for Python Mode (and its Tree Sitter variant) with the following use-package form mysteriously fails:

(use-package python
  :bind (:map python-mode-map
              ("C-x *" . #'whitespace-mode)
              ("C-c C-v" . #'bci/python-check)))

When editing Python Mode buffers, I have python-mode remapped to python-ts-mode via major-mode-remap-alist.

(Note: this question is edited from a previous version which asked more specifically about a failing invocation of keymap-local-set, which turned out to involve a simple mistake involving quoting. However, as my original question was an instance of the XY Problem, the question has been updated to ask about my initial, more general problem.)

M-x version: GNU Emacs 31.0.50 (build 3, x86_64-pc-linux-gnu, GTK+ Version 3.24.38, cairo version 1.16.0) of 2024-11-21

Answer 1

You seem to have already solved the specific issue you were having, but there might be an easier way to approach the general task you are trying to solve: bind-keys.

(bind-keys :map python-base-mode-map
           ("C-x *" . whitespace-mode)
           ("<remap> <python-check>" . bci/python-check))

(C-c C-v is already bound in python-mode-map rather than python-base-mode-map, so if you try to bind the key in the latter map, it won't work.)

If you don't want to remap every binding of python-check, you can bind the specific keys in whichever of the more-specific maps you'd like:

(bind-keys :map python-base-mode-map
           ("C-x *" . whitespace-mode)
           :map python-mode-map
           ("C-c C-v" . bci/python-check)
           :map python-ts-mode-map
           ("C-c C-v" . bci/python-check))

(You can also write [remap python-check] instead of "<remap> <python-check>", but the documentation uses the string form.)

---

On its own in init.el, those will cause an error (because the Python-specific variables aren't defined by default), so you can wrap it using one of these:

(use-package python
  :bind (:map python-base-mode-map
         ("C-x *" . whitespace-mode)
         ("<remap> <python-check>" . bci/python-check)))

(with-eval-after-load 'python
  (bind-keys :map python-base-mode-map
             ("C-x *" . whitespace-mode)
             ("<remap> <python-check>" . bci/python-check)))

(I'd personally recommend use-package, as it also provides other useful utility for package-specific customization, like setting hooks.)