Incremental Search on UTF-8 in Julia Mode

Question

I was wondering if there is any way of searching (incremental search) for a UTF-8 character in julia mode, other than typing the character and copying it into the minibuffer.

I think you can use special input modes to enter unicode characters, but julia-mode is not using the standard tex input mode. Instead, it defines (kbd "TAB") on julia-mode-map which expands to the entry in the hash table, julia-latexsubs.

Also, I don't want to have to look-up the unicode character in the hash table and enter it manually.

EDIT

I'm going to attempt a brief explanation of Stefan's code. The tab key is redefined for isearch-mode-map. First, the binding of newstr creates a temporary buffer and inserts the text from isearch-string. Then run the julia-latexsub function to see if the previous characters are a hash table entry for a utf-8 character. If not, newstr will be nil; otherwise, it will now contain the new character.

If newstr is nil, continue on with isearch as normal; otherwise, update isearch-string with newstr. Then there is some code copied directly from isearch. I'm not familiar with it, but presumably the purpose is to update what happens in the major mode buffer when the isearch-string has changed.

I also found a way to limit the new behavior to Julia-mode. The following seems to work. Insert following newstr.

(if (eq (buffer-local-value 'major-mode (get-buffer (buffer-name))) 
        'julia-mode)
    code-to-evaluate)

Answer 1

AFAIK julia-mode's ad-hoc way to enter non-ASCII characters does not prevent you from using Emacs's input-methods such as C-u C-\ TeX RET, so you can simply use that. Of course, you can additionally use your OS's input method. E.g. I usually type é with Multi_key ' e rather than by using an Emacs input method.

Also, often I circumvent entering non-ASCII characters in text searches by using regexp isearch and using . for the non-ASCII chars.

But if you really want to have exactly julia-mode's input system in Isearch, you can try something like the following:

(defun sm-isearch-julia-latexsub ()
  (interactive)
  (let ((newstr
         (with-temp-buffer
           (insert isearch-string)
           (if (julia-latexsub) nil
             (buffer-substring (point-min) (point-max))))))
    (if (null newstr)
        ;; Run the usual binding of TAB in isearch-mode-map.
        (call-interactively 'isearch-printing-char)
      (setq isearch-string newstr)
      ;; Magic code copied from `isearch-del-char`.
      (setq isearch-message
            (mapconcat #'isearch-text-char-description
                       isearch-string ""))
      (funcall (or isearch-message-function #'isearch-message)
               nil t)
      (if isearch-other-end (goto-char isearch-other-end))
      (isearch-search)
      (isearch-push-state)
      (isearch-update))))

(define-key isearch-mode-map [?\t] 'sm-isearch-julia-latexsub)

The "magic code" is ugly and depends on Isearch internals, so it's probably not really appropriate for julia-mode.el.