Avoid placing safe-local-variable-values in init file

Question

I have a project with a .dir-locals.el file. This file contains some customizations for various project local variables, e.g. include directories for semantic and arguments for clang.

First time opening the project, Emacs asks if I want to consider these variables safe. Obviously I press !, because I don't want to do this every time I open up Emacs.

The problem is that my init.el is part of a git repository, and these local customizations are saved inside the init file as such:

(custom-set-variables
 ;; custom-set-variables was added by Custom.
 ;; If you edit it by hand, you could mess it up, so be careful.
 ;; Your init file should contain only one such instance.
 ;; If there is more than one, they won't work right.
 [...]
 '(safe-local-variable-values
   '((eval semantic-add-system-include "custom/include/path")
   [...]
   ))

But, IMO., these customizations are meant to be local, ie. not included in the git worktree. And I would really like to not having to include them in the init file.

Could I perhaps point to these safe-local-variable-values by storing them inside another elisp file, and then .gitignore that file instead? And how could I achieve this? Or is there a better way?

Edit:

There's a related answer here, but that moves ALL customizations inside another file, whereas I would like to filter ONLY on the safe-local-variable-values (hoping that it's actually possible).

Answer 1

Yes, possible. You need to change the definition of hack-local-variables-confirm. Find the form (customize-push-and-save (if (= char ?!) ...)) and modify it.

I agree with you to some extent: these should be put into another file. But to be honest, I don’t recommend you change the function’s definition, because this is not elegant, so maybe we'll wait and see if there's any other way.

---

BTW, you can take a look at my code. (Please ignore the coding style; I will refactor it someday but not now.) try the code shown below. It doesn't answer your question (or, you could say that it answers, because the files that you trust are where the safe variables are.), but does solve your problem: you just need to put the .dir-locals.el file’s path to your .emacs, then Emacs will never ask you to confirm, because these variables are stored in safe-local-variable-values and thus considered safe:

(let ((shynur/safe-local-variable-values (list)))
  (named-let get-vars ((dir-locals
                        (mapcan (lambda (file-path)
                                  (when (file-exists-p file-path)
                                    (with-temp-buffer
                                      (insert-file-contents file-path)
                                      (read (current-buffer)))))
                                ["~/.emacs.d/.dir-locals.el"
                                 "~/.emacs.d/.dir-locals-2.el"
                                 ;; Files that you trust ...
                                 ])))
    (dolist (mode-vars dir-locals)
      (let ((vars (cdr mode-vars)))
        (if (stringp (car mode-vars))
            (get-vars vars)
          (dolist (var-pair vars)
            (push var-pair shynur/safe-local-variable-values))))))
  (setq safe-local-variable-values (nconc shynur/safe-local-variable-values
                                          safe-local-variable-values)))

Answer 2

Since you said your skills with elisp are very limited, I tried to simplify the solution. Now all you need to do is change the value of your/safe-vars-file.

;;; Put them into your configuration file.

(defconst your/safe-vars-file "C:/Users/shynur/.emacs.d/my-safe-vars.el"
  "The file to store safe local variables.")

(unless (file-exists-p your/safe-vars-file)
  (with-temp-file your/safe-vars-file))

(advice-add 'hack-local-variables-confirm :around
            (lambda (fn &rest args)
              (let ((custom-file your/safe-vars-file))
                (apply fn args))))

(when-let ((your/safe-vars
            (with-temp-buffer
              (insert-file your/safe-vars-file)
              (ignore-errors
                (cadadr (cadar (seq-filter
                                (lambda (quoted-var-list)
                                  (eq (caadr quoted-var-list) 'safe-local-variable-values))
                                (cdr (read (current-buffer))))))))))
  (setq safe-local-variable-values your/safe-vars))