org-mode: getting info about column's header when not visible

Question

In a long org-mode table, the header line

| header1 | header2 | header3 |
|---------+---------+---------|
|         |         |         |

soon disappears from the visible window as one works further down the table. In tables with many columns, I often must try to understand in which column I am in – specifically its header. As far as I see I have three options:

• Scroll up; but it can become unwieldy and often is slow.
• Split the window horizontally, leaving the upper window centred on the header lines; but this steals vertical space.
• Invoke C-c ? which gives info about column & line number; but it doesn't tell me the header of the present column.

I have been unsuccessfully looking for a neater solution. Is there one?

Answer 1

org-table-header-line mode is designed to show the headings of the table when they would otherwise be invisible . It is a minor mode, so you can turn it on the usual way you enable or disable any minor mode: M-x org-table-header-line-mode toggles the mode interactively. From Lisp, (org-table-header-line-mode 1) turns it on and (org-table-header-line-mode 0) turns it off ^footnote. Then when you are looking at a portion of the table near the bottom, making the top of the table (in particular, the line with the table headings) scroll off the top of the window, the top line of the window is overlaid with the line of the table headings, so you can see in which column you are on.

For example, in the following screenshot, you can see that the cursor is in column F (the table that this came from has 40 rows and the columns are various powers of the row number):

---

I mistakenly stated in my comment and in the previous version of this answer that this takes advantage of an Emacs facility, called the header-line (which is like the mode line, except it's at the top of the window, instead of the bottom - in particular, you control it by using the variable header-line-format, similar to how the mode line is controlled with the variable mode-line-format). But the implementation of org-table-header-line-mode does NOT use the Emacs header-line at all. Mea culpa.

---

[footnote] Actually any positive argument enables it and any negative (or zero) argument disables it - just like all minor modes.

Answer 2

Here's a different answer: it implements a small function that gets the header string of the current column and prints it out in the echo area. The implementation is split into a function that does the (not so) heavy lifting and returns the required string (unless there is an error), and a command that prints out the result (or the error message). The latter is bound to a key (C-c z below but you can choose your own) for easy invocation:

(defun ndk/header-of-current-column ()
  (unless (derived-mode-p '(org-mode))
    (user-error "Only Org mode buffers are allowed"))
  (unless (org-at-table-p)
    (user-error "Point is not inside a table"))
  (let ((col (org-table-current-column)))
    (save-excursion
      (goto-char (org-table-begin))
      (let* ((s (org-table-row-get-visible-string (point)))
             (col-header (nth (1- col) (split-string s "|" t))))
        (unless col-header
          (user-error "Col %d - outside the table?" col))
        (string-trim col-header)))))

(defun ndk/print-header-of-current-column ()
  (interactive)
  (message "Header of current column: %s" (ndk/header-of-current-column)))

(define-key org-mode-map (kbd "C-c z") #'ndk/print-header-of-current-column)

The first function could be incorporated into the command org-table-field-info (the command that is bound to C-c ?), so that the column header would be printed together with the other information (row, column and reference notations) that is normally printed by the command.