How to search for headings all the way to the root heading (and preferably file name)

Question

I am new to emacs, and org-mode pulled me away from vim. I am getting a hang of it. One thing I am missing a lot is a hierarchical search in emacs. I wrote a python script for that in vim, and I am looking for a solution in emacs (org-mode).

Let me explain. Let us say, here is the file:

* People
** Software related help
*** John
*** Amit
** Personal
*** John
*** Mike
* Project
** With Mike
*** Website development

When I am searching for a heading, I usually know I am searching for mike, but once I see that there are too many search results (I use 'swiper-all), I want to narrow the search based what the child headings and parent headings contain. In this case, I might want to extend the search to mike people or mike project based on what kind of heading I am searching for.

In other words, if each heading is a node in the tree, I want to search not only in the node, but in the concatenation of all nodes up to the root. (See a couple other nice-to-haves below.)

Is there any solution or package avaiable for this? If not, can you point me to how to go about writing a script/package for this?

---

Nice to haves:

1. Ideally, the file name would be considered as the level zero heading.
2. Ideally, the order of words in the search term does not matter. I sometimes don't remember if I wrote With Mike below Project heading, or wrote Project below Mike heading. In either case, I want to just search for mike project and be able to find what I am looking for.

Answer 1

If you have ivy installed you can use either counsel-org-goto (current buffer only) or counsel-org-goto-all (all currently opened org buffers). Both show the outline path for each heading and therefore let you search hierarchically:

Remark: Those commands should also work for emacs-lisp-mode, markdown-mode and latex-mode.

Ignore search order

To ignore the search order you can customize the ivy completion styles for those commands:

(add-to-list 'ivy-re-builders-alist '(counsel-org-goto . ivy--regex-ignore-order))
(add-to-list 'ivy-re-builders-alist '(counsel-org-goto-all . ivy--regex-ignore-order))

Add filename

To add the filename at the beginning you can advice counsel-outline-candidates:

(defun my-add-filename-to-counsel-outline-candidates (candidates)
  "Add the filename at the beginning for CANDIDATES from `counsel-outline-candidates'."
  (mapcar
   (lambda (candidate)
     (let* ((marker (cdr candidate))
            (filename (buffer-file-name (marker-buffer marker)))
            (filename-abbreviated (when filename (concat (abbreviate-file-name filename) " ")))
            ;; Use this if you want the buffer name. It's a bit shorter.
            ;; (buffername (buffer-name (marker-buffer (cdr candidate))))
            )
       (cons (concat filename-abbreviated (car candidate)) marker)))
   candidates))

(advice-add 'counsel-outline-candidates :filter-return #'my-add-filename-to-counsel-outline-candidates)

Answer 2

For Doom Emacs (with vertico) users there is consult-org-heading command and it's mapped to SPC m . by default. Works in current buffer only.

Search with any word order: